Alec's Web Log

There are a lot of “maximize window to window” to fit screen scripts floating around, but most don’t bother with supporting a dual monitor set up. Here’s a script that resizes the frontmost window of the frontmost application to fit the whole screen of the display that the window is currently in (decided by the position of the top left corner):

set main_display_size to get_main_display_size()
set main_display_width to item 1 of main_display_size
set main_display_height to item 2 of main_display_size


set secondary_display_size to get_secondary_display_size()
set secondary_display_width to item 1 of secondary_display_size
set secondary_display_height to item 2 of secondary_display_size

tell application "System Events"
	set frontmostApplication to name of the first process whose frontmost is true
end tell
tell application frontmostApplication
	set old_bounds to bounds of first window
	if ((item 1 of old_bounds) < 0 or (item 1 of old_bounds) > main_display_width or (item 2 of old_bounds) < 0 or (item 2 of old_bounds) > main_display_height) and (secondary_display_width is not equal to -1 and secondary_display_height is not equal to -1) then
		tell application "Finder"
			set desktop_bounds to get bounds of window of desktop
		end tell
		
		set bounds of first window to {item 1 of desktop_bounds, item 2 of desktop_bounds, (item 1 of desktop_bounds) + secondary_display_width, (item 2 of desktop_bounds) + secondary_display_height}
		
	else
		set bounds of first window to {0, 0, main_display_width, main_display_height}
	end if
end tell

on get_main_display_size()
	set command to "/usr/sbin/system_profiler SPDisplaysDataType"
	set output to (do shell script command)
	set AppleScript's text item delimiters to "Resolution: "
	set displays to text items of output
	set i to 2
	repeat ((length of displays) - 1) times
		if (offset of "Main Display: Yes" in (item i of displays)) is not equal to 0 then
			set word_list to words of item i of displays
			set main_display_width to item 1 of word_list
			set main_display_height to item 3 of word_list
		end if
		set i to i + 1
	end repeat
	return {main_display_width as integer, main_display_height as integer}
end get_main_display_size

on get_secondary_display_size()
	set command to "/usr/sbin/system_profiler SPDisplaysDataType"
	set output to (do shell script command)
	set AppleScript's text item delimiters to "Resolution: "
	set displays to text items of output
	set i to 2
	set found to false
	repeat ((length of displays) - 1) times
		if (offset of "Main Display: Yes" in (item i of displays)) is equal to 0 then
			set word_list to words of item i of displays
			set secondary_display_width to item 1 of word_list
			set secondary_display_height to item 3 of word_list
			set found to true
		end if
		set i to i + 1
	end repeat
	if found then
		return {secondary_display_width as integer, secondary_display_height as integer}
	else
		return {-1, -1}
	end if
end get_secondary_display_size

Here’s my new definitive “gather all windows to main display” applescript:

set main_display_size to get_main_display_size()
set main_display_width to item 1 of main_display_size
set main_display_height to item 2 of main_display_size

tell application "System Events"
  set frontmostApplication to name of the first process whose frontmost is true
end tell

tell application "System Events" to set the visible of every process to true

tell application "System Events" to set theApps to (name of every process whose visible is true)
repeat with theApp in theApps
  try
    tell application theApp
      set i to 1
      set stack_x to 0
      set stack_y to 0
      if theApp is "Finder" then
        set real_windows to item 1 of windows
      else
        set real_windows to windows
      end if
      repeat (length of real_windows) times
        try
          set old_bounds to bounds of (window i)
          -- only mess with windows whose top left corner is not on main display
          if (item 1 of old_bounds) < 0 or (item 1 of old_bounds) ≥ main_display_width or (item 2 of old_bounds) < 0 or (item 2 of old_bounds) ≥ main_display_height then
            --      if (item 1 of old_bounds
            set new_x1 to (((item 1 of old_bounds) mod main_display_width) + main_display_width) mod main_display_width
            if new_x1 > main_display_width / 2 then
              set new_x1 to stack_x
              set stack_x to stack_x + 10
            end if
            set new_y1 to (((item 2 of old_bounds) mod main_display_height) + main_display_height) mod main_display_height
            if new_y1 > main_display_height / 2 then
              set new_y1 to stack_y
              set stack_y to stack_y + 10
            end if
            set new_x2 to new_x1 + ((item 3 of old_bounds) - (item 1 of old_bounds))
            if new_x2 > main_display_width then
              set new_x2 to main_display_width
            end if
            set new_y2 to new_y1 + ((item 4 of old_bounds) - (item 2 of old_bounds))
            if new_y2 > main_display_height then
              set new_y2 to main_display_height
            end if
            
            set new_bounds to {new_x1, new_y1, new_x2, new_y2}
            set bounds of (window i) to new_bounds
          end if
        end try
        set i to i + 1
      end repeat
    end tell
  end try
end repeat
-- return focus to original frontmost
tell application frontmostApplication
  activate
end tell

on get_main_display_size()
  set command to "/usr/sbin/system_profiler SPDisplaysDataType"
  set output to (do shell script command)
  set AppleScript's text item delimiters to "Resolution: "
  set displays to text items of output
  set i to 2
  repeat ((length of displays) - 1) times
    if (offset of "Main Display: Yes" in (item i of displays)) is not equal to 0 then
      set word_list to words of item i of displays
      set main_display_width to item 1 of word_list
      set main_display_height to item 3 of word_list
    end if
    set i to i + 1
  end repeat
  return {main_display_width as integer, main_display_height as integer}
end get_main_display_size

Here’s a handy applescript to split your frontmost application’s front most two windows on the main display:

set main_display_size to get_main_display_size()
set main_display_width to item 1 of main_display_size
set main_display_height to item 2 of main_display_size

tell application "System Events"
	set frontmostApplication to name of the first process whose frontmost is true
end tell
tell application frontmostApplication
	set bounds of first window to {0, 0, main_display_width / 2, main_display_height}
	set bounds of second window to {main_display_width / 2, 0, main_display_width, main_display_height}
end tell

on get_main_display_size()
	set command to "/usr/sbin/system_profiler SPDisplaysDataType"
	set output to (do shell script command)
	set AppleScript's text item delimiters to "Resolution: "
	set displays to text items of output
	set i to 2
	repeat ((length of displays) - 1) times
		if (offset of "Main Display: Yes" in (item i of displays)) is not equal to 0 then
			set word_list to words of item i of displays
			set main_display_width to item 1 of word_list
			set main_display_height to item 3 of word_list
		end if
		set i to i + 1
	end repeat
	return {main_display_width as integer, main_display_height as integer}
end get_main_display_size

Note:This only works if you save this an a .scpt script file, not as an application as it will just think itself is the frontmost application and do nothing.